mode_setup;

em#:=10pt#; cap#:=7pt#;
thin#:=1/3pt#; thick#:=5/6pt#;
bar#:=.8pt#;
stem#:=.9pt#;
o#:=1/5pt#;

define_pixels(em,cap);
define_blacker_pixels(thin,thick,bar,stem);
define_corrected_pixels(o);

curve_sidebar=round 1/18em;

beginchar("T",0.6em#,cap#,0); % "The letter T"; % 0039
penpos1(bar,75);
penpos2(bar,72);
penpos3(bar,70);
pentaper2(.4,.6);
x1l=0; y1=y3l;
x2=.5w; y2=.5[y1,y3]; .8[y2r,y3r]=h;
x3=w;
penpos4(10/9stem,argd(z3-z1));
penpos5(10/9stem,20);
penpos6(10/9stem,10);
z2=z4; pentaper4(.25,.1);
x5r=x4r; y5=2/3h;
x6=x5; y6=0;
pentaper5(.4,0);
dz5=down;
penstroke(1,2,3); penstroke(4,5,6);
labels.top(1r,1,5,6,2r);
labels.lft(1l,5l,4l);
labels.rt(3,3r,5r,6r,4r);
labels.bot(3l,6l,2l);
labels(2);
endchar;

beginchar("S",5/9em#,cap#,0); % "The letter S"; % 0039
penpos1(bar,70);
penpos2(bar,80);
penpos3(.5[bar,thick],200);
penpos5(.5[bar,thick],210);
penpos6(bar,80);
penpos7(.25[bar,thick],75);
pentaper2(.4,.6); pentaper6(.3,.5);
x1=x5; y1r=.94h+o;
x2=x4=x6=.5w; y2r=h+o; y4=.54h; y6l=-o;
x3r=.04em; y3=.5[y4,y2];
x5l=w-.03em; y5=.5[y4,y6];
.5[x7l,x7]=.04em; y7l=.1h-o;
path trial; trial=z3{down}..z4..{down}z5;
dz4=direction 1 of trial;
penpos4(thick,argd(dz4)-90);
dz3=dz5=down;
dz2=dz6=left;
penstroke(1,2,3,4,5,6,7);
penlabels(1,2,3,4,5,6,7);
endchar;

beginchar("O",0.8em#,cap#,0); "The letter O";
 penpos1(thick,10); penpos2(.1[thin,thick],90-10);
 penpos3(thick,180+10); penpos4(thin,270-10);
 x1l=w-x3l=curve_sidebar; x2=x4=.5w;
 y1=.49h; y2l=-o; y3=.51h; y4l=h+o;
 dz1=down; dz2=right; dz3=up; dz4=left;
 penstroke(1,2,3,4,cycle);
 penlabels(1,2,3,4); endchar;

beginchar("I",.35em#,cap#,0); "The letter I";
 penpos1(stem,15); penpos2(stem,12); penpos3(stem,10);
 x1=x2=x3=.5w; y1=h; y2=.55h; y3=0;
 pentaper2(.25,.1); dz2=down; penstroke(1,2,3);
 penlabels(1,2,3); endchar;

ligtable "T": "T" kern .05em#, "O" kern -.05em#;
fontdimen 1: 0, 1/3em#, 1/6em#, 1/9em#, cap#, em#, 1/9em#;
designsize:=em#;
end